14 script AutoHotkey có thể sử dụng hàng ngày

Mỗi giây bạn dành để thực hiện các tác vụ tầm thường, thừa thãi trên màn hình sẽ cộng lại thành hàng giờ lãng phí trong cuộc sống cho những thứ lặp lại không thể tránh khỏi. Các script AutoHotkey này sẽ lấy lại thời gian đó và biến đổi cách bạn tương tác với PC của mình.

1. Tìm kiếm nhanh bất kỳ văn bản nào đã chọn trên Google

Nếu bạn mới sử dụng AutoHotkey, đây là ngôn ngữ script mạnh mẽ để tự động hóa các tác vụ lặp lại trong Windows. Chỉ với một vài dòng code, bạn có thể sắp xếp hợp lý các hành động hàng ngày - như tìm kiếm trên web chỉ bằng một lần nhấn phím.

Script đầu tiên này cho phép bạn highlight bất kỳ văn bản nào, nhấn Ctrl + Shift + S và một tab mới sẽ tự động mở ra với kết quả tìm kiếm trên Google cho lựa chọn của bạn. Không cần phải mở trình duyệt, nhập vào thanh tìm kiếm và nhấn Enter, script này thực hiện tất cả chỉ trong một lần di chuyển.

#Requires AutoHotkey v2.0

^+s:: {
Clipboard := ""
Send("^c")
ClipWait()
Run "https://www.google.com"
WinWaitActive "Google - Google Chrome" ; Adjust window title as needed
Sleep 500
Send("^v")
Sleep 100
Send("{Enter}")
}

Hoàn hảo cho việc nghiên cứu nhanh, xác minh thuật ngữ hoặc tìm kiếm tài liệu tham khảo mà không mất động lực. Giống như có một trợ lý nghiên cứu sống trong clipboard của bạn.

2. Hủy bất kỳ ứng dụng nào bị đóng băng mà không cần Task Manager

Khi một ứng dụng bị khóa hoặc từ chối tắt, Ctrl + Alt + K sẽ tắt ứng dụng đó mà không cần thực hiện thêm bất kỳ bước nào. Nó đóng cửa sổ đang hoạt động mà không cần hỏi bất kỳ câu hỏi nào. Điều đó có nghĩa là bạn có thể quay lại những gì quan trọng chỉ trong vài giây.

#Requires AutoHotkey v2.0

^!k:: {
pid := WinGetPID("A")
if (pid) {
procName := ""
for proc in ComObjGet("winmgmts:").ExecQuery("SELECT Name, ProcessId FROM Win32_Process WHERE ProcessId = " pid) {
procName := proc.Name
}
if (procName != "explorer.exe") {
Run('taskkill /PID ' . pid . ' /F', "", "Hide")
} else {
MsgBox("Cannot kill explorer.exe! Killing this will crash your taskbar.")
}
}
}

Script này sẽ cứu bạn khỏi màn hình bị đóng băng, trình phát video lặp lại và thậm chí cả Photoshop khi nó gặp sự cố. Hãy nhớ rằng cũng có một số thủ thuật ẩn của Windows để đóng ứng dụng ngay lập tức, rất đáng để khám phá.

3. Tắt tiếng hệ thống ngay lập tức

Mỗi bàn phím dường như có một tổ hợp phím khác nhau để tắt tiếng. Tải script này xuống mỗi thiết bị sẽ tạo ra một giải pháp chung cho một vấn đề gây khó chịu chung.

#Requires AutoHotkey v2.0

^!m:: ; Ctrl+Alt+M to toggle mute
{
Send("{Volume_Mute}")
}

Cho dù ai đó gọi điện bất ngờ hay bạn mở một trang web ồn ào giữa một căn phòng yên tĩnh, shortcut này sẽ giúp bạn kiểm soát ngay lập tức. Ctrl + Alt + M sẽ bật hoặc tắt tiếng hệ thống. Không cần loay hoay với các phím media trên bàn phím, không gây mất tập trung, chỉ cần im lặng khi bạn cần nhất.

4. Ánh xạ lại phím Caps Lock thành Ctrl (mà không làm mất phím Caps Lock)

Nếu bạn liên tục sử dụng các phím tắt Ctrl như sao chép, dán, hoàn tác, chọn tất cả, ngón út sẽ cảm ơn bạn vì script này. Script này khiến phím Caps Lock hoạt động giống như phím Ctrl, tiện dụng hơn nhiều, đặc biệt là nếu bạn ở bên trái bàn phím cả ngày.

#Requires AutoHotkey v2.0

SetCapsLockState("AlwaysOff")

CapsLock:: {
Send("{Ctrl down}")
KeyWait("CapsLock")
Send("{Ctrl up}")
}

+CapsLock:: SetCapsLockState("Toggle")

Đừng lo, bạn không mất phím Caps Lock. Script này gán lại chức năng bật/tắt phím Caps Lock thành Ctrl + Caps, nếu bạn cần dùng vì bất kỳ lý do gì. Khi sử dụng hàng ngày, điều này giúp việc nhấn phím Ctrl nhanh và thoải mái hơn bao giờ hết.

Script này cũng có thể áp dụng cho bất kỳ nút nào được đặt ở vị trí bất tiện trên bàn phím. Chỉ cần hoán đổi các phím trong chính script và thay thế chúng bằng bất kỳ phím nào khác khó chạm tới.

5. Khởi chạy ứng dụng được sử dụng nhiều nhất bằng một tổ hợp phím

Nếu bạn đã bỏ qua Notepad, thì đã đến lúc xem xét lại. Cho dù bạn đang ghi lại ý tưởng, viết code tạm thời hay xóa văn bản trước khi mất, Notepad là lựa chọn phù hợp cho tốc độ và sự đơn giản.

#Requires AutoHotkey v2.0

^!n:: Run("notepad.exe")

Với tổ hợp phím này, Ctrl + Alt + N sẽ khởi chạy Notepad ngay lập tức. Bạn có thể hoán đổi bất kỳ ứng dụng nào: Calculator, Word, Outlook, bất kỳ ứng dụng nào bạn chọn. Nó cho phép bạn tiết kiệm thời gian bằng cách cắt hoàn toàn menu Start và thanh tìm kiếm.

6. Mở thư mục yêu thích

Chỉ cần một lần nhấn phím là bạn có thể mở thư mục Documents của mình hoặc bất kỳ thư mục nào bạn tin tưởng. Cho dù đó là kho lưu trữ dự án, bản tải xuống hay kho lưu trữ của khách hàng, bạn không cần phải nhấp chuột xung quanh như thể đang ở năm 2009.

#Requires AutoHotkey v2.0

userProfile := EnvGet("USERPROFILE")

^!d:: Run(userProfile "\Documents")
^!p:: Run(userProfile "\Pictures")
^!v:: Run(userProfile "\Videos")

Ví dụ, bạn có thể ánh xạ Ctrl + Alt + D đến Documents, Ctrl + Alt + P tới Pictures và Ctrl + Alt + V vào thư mục Videos. Bộ nhớ cơ bắp rất cơ bản, vì vậy bạn hầu như không phải nghĩ về những gì mình đang làm.

7. Chuyển đổi các file ẩn trong File Explorer

Có rất nhiều cách để ẩn các file hoặc thư mục trong Windows, nhưng làm sao để chúng dễ dàng hiển thị trở lại. Script này chuyển đổi khả năng hiển thị các file ẩn mà không cần phải vào cài đặt File Explorer hoặc nhấp vào 4 menu sâu. Nó thậm chí còn tự động khởi động lại Explorer để áp dụng thay đổi.

#Requires AutoHotkey v2.0

^!h:: {
toggleHiddenFiles()
}

toggleHiddenFiles() {
psCmd := "
(
$key = 'HKCU:\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced'
$val = Get-ItemProperty -Path $key -Name Hidden
if ($val.Hidden -eq 1) {
Set-ItemProperty -Path $key -Name Hidden -Value 2
} else {
Set-ItemProperty -Path $key -Name Hidden -Value 1
}
(New-Object -ComObject Shell.Application).Windows() | ForEach-Object { $_.Refresh() }
)"

RunWait("powershell -Command " . Chr(34) . psCmd . Chr(34), "", "Hide")
}

Ctrl + Alt + H. Vậy là xong! Bạn có thể thấy .git, .env và mọi file lén lút khác ngay lập tức. Thiết yếu đối với các nhà phát triển, quản trị viên hệ thống và bất kỳ ai làm việc ẩn danh.

8. Dán ngay địa chỉ email

Điều này rất đơn giản - và vô cùng hữu ích - đến mức gần như giống như gian lận. Bất cứ khi nào bạn điền vào biểu mẫu, đăng nhập vào thiết bị mới hoặc đăng ký dịch vụ không xác định, việc nhập "@@" sẽ ngay lập tức dán địa chỉ email của bạn.

#Requires AutoHotkey v2.0

::@@::your.email@example.com

Bạn cũng có thể thiết lập các biến thể của riêng mình, chẳng hạn như "@@w" cho công việc hoặc "@@p" cho cá nhân. Đây là một shortcut nhỏ, nhưng nó tăng lên nhanh chóng. Một việc ít hơn mà bạn sẽ phải nhập 50 lần một tuần.

9. Dán template email hoặc đoạn văn bản nhanh

Bạn có thể sử dụng điều này để ký email, mẫu báo cáo lỗi, thậm chí là phản hồi hướng dẫn được viết sẵn. Bạn có thể chèn ngắt dòng bằng {Enter} và định dạng theo ý muốn.

#Requires AutoHotkey v2.0

::sig::Best regards,{Enter}Your Name{Enter}your.email@example.com

Khi bắt đầu tự động hóa các tương tác nhỏ này, bạn sẽ nhận ra mình thường xuyên lặp lại như thế nào. Hãy loại bỏ điều đó khỏi ngày của mình và bạn sẽ cảm thấy sự khác biệt.

10. Dấu ngày và giờ bất cứ nơi nào bạn nhập

Bạn đã bao giờ nhập ghi chú cuộc họp, mục nhật ký hoặc nhật ký thay đổi và phải dừng lại để kiểm tra thời gian chưa? Script này khiến điều đó trở nên lỗi thời. Nhập "ts" và dấu ngày/giờ đầy đủ sẽ xuất hiện, được định dạng theo đúng cách bạn thích.

#Requires AutoHotkey v2.0

::ts::
{
; Get the current time components
hour12 := A_Hour
ampm := "am"

if (hour12 = 0) {
hour12 := 12
ampm := "am"
} else if (hour12 >= 12) {
if (hour12 > 12)
hour12 -= 12
ampm := "pm"
}

FormatTime := Format("{:02}/{:02}/{} {:d}:{:02}{}", A_MM, A_DD, A_YYYY, hour12, A_Min, ampm)
Send(FormatTime)
Return
}

Một lợi ích chính của script đơn giản này là dấu thời gian tăng cường bảo mật dữ liệu trong các hệ thống kỹ thuật số. Bạn có tùy chọn chỉnh sửa định dạng ngày thành DD/MM/YYY hoặc thay đổi đồng hồ thành giờ 24 giờ, nếu điều đó hữu ích cho công việc của bạn. Nhanh, im lặng và hoàn hảo cho những ai phải ghi chép khi đang làm việc.

11. Tự động sửa lỗi đánh máy thường gặp nhất

Trình duyệt và Word đã có tính năng tự động sửa lỗi, nhưng chúng không bao gồm mọi ứng dụng. Gần như chắc chắn rằng chúng không hoạt động trong các công cụ ít người biết đến hoặc bảng điều khiển nội bộ. Script này hoạt động trên toàn hệ thống. Bạn có thể truy cập script tự động sửa lỗi tại đây.

Đây là top của tất cả các script và có khả năng nó sẽ tiếp tục phát triển khi bạn nhận ra mình thường xuyên gõ sai từ trên bàn phím như thế nào. Bạn có thể dễ dàng mở script này để mở rộng danh sách lỗi đánh máy của riêng mình. Nếu bạn đánh máy nhanh nhưng đôi khi cẩu thả, script này giống như có ai đó đang giúp bạn theo dõi phần chính tả.

12. Công cụ thay đổi kích thước cửa sổ thông minh để tăng năng suất khi chia đôi màn hình

Công cụ này giống như tính năng chụp màn hình gốc của Windows, nhưng có độ chính xác tức thì. Ctrl + Alt + Mũi tên trái sẽ thay đổi kích thước cửa sổ hiện tại của bạn sang nửa bên trái của màn hình, trong khi Ctrl + Alt + Mũi tên phải sẽ chuyển cửa sổ sang nửa bên phải. Không cần kéo lê và không cần vật lộn để có được sự căn chỉnh hoàn hảo.

#Requires AutoHotkey v2.0

^!Left::SnapHalf("left")
^!Right::SnapHalf("right")

SnapHalf(side) {
hwnd := WinGetID("A")
if !hwnd {
MsgBox("No active window.")
return
}

try WinRestore(hwnd)
Sleep(100)

if !WinExist("ahk_id " hwnd) {
MsgBox("Window no longer exists.")
return
}

MonitorGetWorkArea(1, &left, &top, &right, &bottom)
width := right - left
height := bottom - top

if (side = "left") {
x := left
} else if (side = "right") {
x := left + width // 2
} else {
MsgBox("Invalid side.")
return
}

; Use MoveWindow API instead of WinMove for better compatibility
success := DllCall("MoveWindow"
, "Ptr", hwnd
, "Int", x
, "Int", top
, "Int", width // 2
, "Int", height
, "Int", true)

if !success {
MsgBox("MoveWindow API failed. Window may not support repositioning.")
}
}

Đây là giải pháp cứu cánh cho công việc trên màn hình kép, chỉnh sửa cạnh nhau hoặc điền thông tin được tham chiếu vào bảng tính. Sử dụng một lần và bạn sẽ không bao giờ phải thay đổi kích thước cửa sổ theo cách thủ công nữa.

13. Di chuyển cửa sổ đang hoạt động sang màn hình tiếp theo

Nếu bạn làm việc với màn hình kép (hoặc nhiều màn hình hơn), quản lý cửa sổ luôn là một trận chiến nhỏ. Script này không cầu kỳ - nó chỉ đơn giản là di chuyển cửa sổ hiện tại sang màn hình tiếp theo ngay lập tức.

#Requires AutoHotkey v2.0

^+w::MoveWindowToNextMonitor()

MoveWindowToNextMonitor() {
hwnd := WinGetID("A")
if !hwnd {
MsgBox("No active window found.")
return
}

; Get current window position
WinGetPos(&wx, &wy, &ww, &wh, hwnd)

monitorCount := MonitorGetCount()
if (monitorCount ; Only one monitor: just maximize the window on current monitor
WinMaximize(hwnd)
return
}

; Find which monitor the window is mostly on (center point)
centerX := wx + ww // 2
centerY := wy + wh // 2
curMonitor := GetMonitorFromPoint(centerX, centerY)
nextMonitor := curMonitor + 1
if (nextMonitor > monitorCount)
nextMonitor := 1

; Get work area of the next monitor
MonitorGetWorkArea(nextMonitor, &left, &top, &right, &bottom)
width := right - left
height := bottom - top

; Move and resize the window fullscreen on the next monitor
success := DllCall("MoveWindow"
, "Ptr", hwnd
, "Int", left
, "Int", top
, "Int", width
, "Int", height
, "Int", true)

if !success {
MsgBox("Failed to move window to monitor " . nextMonitor)
}
}

GetMonitorFromPoint(x, y) {
MONITOR_DEFAULTTONEAREST := 2
hMon := DllCall("MonitorFromPoint", "Int", x, "Int", y, "UInt", MONITOR_DEFAULTTONEAREST, "Ptr")
return MonitorIndexFromHandle(hMon)
}

MonitorIndexFromHandle(hMonitor) {
count := MonitorGetCount()
Loop count {
MonitorGet(A_Index, &l, &t, &r, &b)
midX := l + (r - l) // 2
midY := t + (b - t) // 2
h := DllCall("MonitorFromPoint", "Int", midX, "Int", midY, "UInt", 2, "Ptr")
if (h = hMonitor)
return A_Index
}
return 1
}

Script phức tạp này khiến việc kéo cửa sổ trở nên lỗi thời. Để tận dụng tối đa, hãy xem bài viết về cách thiết lập màn hình kép này.

14. Chuyển đổi văn bản đã chọn thành chữ hoa đầu câu

Script này giải quyết một sự khó chịu phổ biến đáng ngạc nhiên - khi bạn sao chép văn bản bằng chữ in hoa hoặc cấu trúc không nhất quán và muốn viết ra ở định dạng có thể sử dụng được. Chỉ cần nhấn Ctrl + Alt + C, và bất kỳ nội dung nào bạn đã highlight sẽ ngay lập tức được chuyển thành chữ hoa đầu câu: Chữ cái đầu tiên viết hoa, mọi nội dung khác viết thường.

#Requires AutoHotkey v2.0

^!c:: ; Ctrl + Alt + C
{
ClipSaved := ClipboardAll() ; Backup clipboard
A_Clipboard := "" ; Clear clipboard for fresh copy

Send("^c") ; Copy selected text
if !ClipWait(1)
{
MsgBox("No text was copied. Please select some text first.")
return
}

lowerText := StrLower(A_Clipboard)
; Capitalize the first letter, preserve rest
if StrLen(lowerText) > 0
formattedText := StrUpper(SubStr(lowerText, 1, 1)) . SubStr(lowerText, 2)
else
formattedText := lowerText

A_Clipboard := formattedText
Sleep(50)
Send("^v") ; Paste the modified text

Sleep(50)
A_Clipboard := ClipSaved ; Restore original clipboard
}

Script này rất tuyệt để sửa các câu được viết lộn xộn mà không cần phải viết lại thủ công. Nó sao chép, xử lý và dán phần bạn chọn một cách liền mạch, đồng thời vẫn giữ nguyên nội dung clipboard gốc.

Bàn phím của bạn không chỉ là một công cụ, mà còn là trung tâm chỉ huy. 14 script này cung cấp cho bạn khả năng kiểm soát, tốc độ và sự linh hoạt mà bạn không nhận ra là mình đang thiếu. Cho dù bạn áp dụng một vài hay tất cả chúng, thì mỗi script đều tạo nên quy trình làm việc nhanh chóng, mượt mà và hiệu quả hơn.

Hãy thử chúng, sửa đổi những gì không phù hợp, biến chúng thành của riêng bạn, sau đó quên rằng chúng từng là "script" ngay từ đầu. Chẳng bao lâu nữa, mỗi script trong số chúng sẽ lặng lẽ trở thành tiện ích tự nhiên thứ hai.