10 script AutoHotKey giúp cuộc sống dễ dàng hơn

Mọi người đã tạo các script PowerShell trên PC Windows của mình trong nhiều năm, nhưng nhiều script phải chạy thủ công. Với AutoHotkey (phiên bản 2), bạn có thể tạo lại các script này và liên kết chúng với những phím tắt, khiến chúng giống như các tính năng tích hợp sẵn của Windows mà Microsoft đã quên đề cập.

10. App Launcher nhanh cá nhân

Các ứng dụng như Notepad, Calculator và Paint thường bị ẩn khỏi desktop vì chúng không quá quan trọng. Nhưng thỉnh thoảng, bạn thấy mình phải săn lùng những ứng dụng này vì tiện ích nhanh chóng của chúng. Vì vậy, thay vì xem qua menu Start hoặc biểu tượng trên desktop, hãy tạo một menu tùy chỉnh xuất hiện ngay lập tức khi bạn nhấn phím Windows + M bằng cách sử dụng script bên dưới.

#Requires AutoHotkey v2.0

#m::{
MyMenu := Menu()
MyMenu.Add("Calculator", (*) => Run("calc.exe"))
MyMenu.Add("Sticky Notes", (*) => Run("explorer.exe shell:AppsFolder\Microsoft.MicrosoftStickyNotes_8wekyb3d8bbwe!App"))
MyMenu.Add("Notepad", (*) => Run("notepad.exe"))
MyMenu.Add("Paint", (*) => Run("mspaint.exe"))
MyMenu.Show()
}

9. Cuộn ngang được thực hiện nhất quán

Giữ Shift + Con lăn chuột để cuộn ngang không hoạt động với tất cả các ứng dụng bạn sử dụng. Thật đáng buồn, mọi người sử dụng thao tác này thường xuyên, đặc biệt là những ai thích xem các code snippet hoặc thiết kế trong CAD. Vì vậy, hãy tạo script riêng của mình để cuộn ngang hoạt động với bất kỳ ứng dụng nào bạn sử dụng.

Tạo một script với các mục sau để tạo phiên bản của riêng bạn:

#Requires AutoHotkey v2.0

#HotIf GetKeyState("Shift", "P")
WheelUp::Send("{WheelLeft}")
WheelDown::Send("{WheelRight}")
#HotIf

Bằng cách giữ Shift và con lăn chuột, bạn có thể cuộn sang trái và phải thay vì lên hoặc xuống. Tính năng này hoạt động trong bất kỳ chương trình nào hỗ trợ cuộn ngang, từ bảng tính Excel, trình chỉnh sửa ảnh đến trình duyệt web có nội dung rộng.

8. Truy cập tức thời vào bất kỳ thư mục nào

Nhiều người thường sắp xếp các file của mình vào những thư mục. Tuy nhiên, đôi khi, tạo quá nhiều thư mục con khiến việc truy cập thư mục dự án phải mất nhiều lần nhấp chuột để mở. Bạn có thể dễ dàng tạo một script liên kết với Ctrl + ALT + D để mở ngay một thư mục dự án đã chỉ định.

Đây là script:

#Requires AutoHotkey v2.0

^!d::Run('explorer.exe "C:\Users\jricm\Downloads"')

7. Mở rộng văn bản nhanh cho các cụm từ hàng ngày

Bạn có thích ý tưởng sử dụng mã alt của Windows để chèn các ký tự đặc biệt một cách dễ dàng và nhanh chóng không? Hãy áp dụng cách tiếp cận tương tự với một script AHK cho phép bạn sử dụng các shortcut cho những cụm từ phổ biến mà mình thường sử dụng. Hãy tạo script này để tự mình thử:

#Requires AutoHotkey v2.0
#SingleInstance Force

::gm::Good morning
::ty::Thank you
::brb::Be right back

Với ví dụ này, bất cứ khi nào bạn nhập "gm" theo sau là dấu cách (hoặc Enter), nó sẽ ngay lập tức mở rộng thành "Good morning". Tương tự với "ty", mở rộng thành "Thank you" và "brb" thành "Be right back". Điều này hoạt động trong bất kỳ ứng dụng nào mà bạn có thể nhập và nó đặc biệt hữu ích khi bạn trả lời tin nhắn trong suốt cả ngày.

6. Điều khiển âm lượng tùy chỉnh bằng bàn phím

Nhiều người luôn cảm thấy khó khăn khi điều khiển âm lượng của Windows. Bạn có thể nhấp vào biểu tượng loa nhỏ trên khay hệ thống hoặc tìm kiếm các nút âm lượng trên bàn phím, rất khó tìm, đặc biệt là khi bạn làm việc lúc tắt đèn. Hãy thay bằng thứ gì đó nhanh và trực quan hơn!

Vì ngón tay bạn luôn dán chặt vào các hàng phím chính, nên việc liên kết chức năng điều khiển âm lượng với CTRL + Dấu phẩy hoặc CTRL + Dấu chấm để điều khiển âm lượng và CTRL + M để tắt tiếng và bật tiếng là hợp lý. Đây là script bạn có thể sử dụng:

#Requires AutoHotkey v2.0
#SingleInstance Force

^,::Send("{Volume_Down}") ; Ctrl + ^.::Send("{Volume_Up}") ; Ctrl + > (period)
^m::Send("{Volume_Mute}") ; Ctrl + M

5. Căn giữa con trỏ chuột ngay lập tức

Điều này nghe có vẻ đơn giản, nhưng nó thực sự hữu ích, đặc biệt là nếu bạn làm việc với nhiều màn hình hoặc thiết lập siêu rộng duy nhất. Hotkey này sẽ căn giữa con trỏ chuột khi bạn nhấn Ctrl + Alt + C. Đây là script bạn cần tạo:

#Requires AutoHotkey v2.0
^!c:: {
WinGetPos(&x, &y, &w, &h, "A")
MouseMove(x + w/2, y + h/2)
}

Script tìm điểm chính xác ở giữa cửa sổ đang hoạt động của bạn và di chuyển chuột đến đó ngay lập tức. Nó hoạt động với bất kỳ chương trình và bất kỳ kích thước cửa sổ nào, ngay cả khi một phần cửa sổ đó nằm ngoài màn hình. Bạn có thể thường sử dụng script này nhất khi chuyển đổi giữa các ứng dụng khác nhau và muốn nhanh chóng tập trung vào cửa sổ mới mà không phải nghĩ đến vị trí con chuột của mình đã dừng lại.

4. Tự động sắp xếp thư mục tải xuống

Thư mục Downloads thường rất hỗn loạn. Ảnh chụp màn hình lẫn lộn với PDF, file nhạc bên cạnh trình cài đặt ngẫu nhiên. Bạn có thể sắp xếp thủ công, nhưng ai có thời gian để sắp xếp file khi đang làm việc chứ?

Script hotkey này chạy ở chế độ nền và tự động sắp xếp các file tải xuống mới vào những thư mục được sắp xếp dựa trên loại file. Nhấn F12 để bật nó và cứ 5 giây nó sẽ quét thư mục Downloads của bạn, rồi di chuyển các file đến những thư mục con thích hợp. Các file PDF và tài liệu Word sẽ vào thư mục "Docs", hình ảnh sẽ vào "Images", file nhạc vào "Music", v.v... Đây là cách thiết lập:

#Requires AutoHotkey v2.0
downloads:="C:\Users\jricm\Downloads", interval:=5000
ext:=Map("pdf","Docs","docx","Docs","xlsx","Docs","txt","Text","jpg","Images","png","Images","mp3","Music","mp4","Videos","exe","Programs","zip","Archives")
F12:: {
static on:=false
on:=!on, SetTimer(MoveFiles, on?interval:0)
ToolTip("AutoSort: " (on?"ON":"OFF")), SetTimer(() => ToolTip(), -1500)
}
MoveFiles() {
Loop Files downloads "\*.*", "F"
if ext.Has(e:=A_LoopFileExt) {
d:=downloads "\" ext[e]
if !DirExist(d)
DirCreate(d)
try FileMove(A_LoopFilePath, d "\" A_LoopFileName, 1)
}
}

3. Khởi chạy nhiều ứng dụng cho quy trình công việc cụ thể

Nhiều người thích sử dụng Virtual Desktops của Windows để sắp xếp những tác vụ khác nhau. Thật đáng tiếc khi nó không cho phép bạn tự động mở một số ứng dụng nhất định hoặc thay đổi ứng dụng trên mỗi desktop ảo. Để khắc phục, hãy sử dụng AutoHotkey để mở nhiều ứng dụng chỉ bằng một lần nhấn phím. Đây là script bạn có thể sử dụng:

#Requires AutoHotkey v2.0

+1:: {
Run('"C:\Users\jricm\AppData\Local\Programs\Microsoft VS Code\Code.exe"')
Run('"C:\Program Files\JetBrains\DataGrip 2023.3.4\bin\datagrip64.exe"')
Run('"C:\Program Files\Docker\Docker\Docker Desktop.exe"')
}

2. Luôn hiển thị các cửa sổ quan trọng

Có rất nhiều lần bạn muốn một cửa sổ luôn hiển thị, chẳng hạn như khi đang làm theo hướng dẫn, kiểm tra ghi chú hoặc trò chuyện với mọi người. Windows không cung cấp cho bạn cách dễ dàng để thực hiện việc này. Vì vậy, hãy tạo một script cho mục đích cụ thể này.

#Requires AutoHotkey v2.0

ScrollLock:: {
try {
activeHwnd := WinGetID("A")
isTopMost := WinGetExStyle(activeHwnd) & 0x8 ; 0x8 = WS_EX_TOPMOST

WinSetAlwaysOnTop(!isTopMost, activeHwnd)
SetScrollLockState(isTopMost ? "Off" : "On")

ToolTip("Always On Top: " (isTopMost ? "OFF" : "ON"))
SetTimer(() => ToolTip(), -1000)
}
}

Với script trên, bạn chỉ cần nhấn phím Scroll Lock khi cửa sổ đang hoạt động và nó sẽ luôn ở trên cùng của mọi thứ khác. Script cung cấp cho bạn một chú giải công cụ nhanh và bật hoặc tắt đèn Scroll Lock trên bàn phím, vì vậy bạn luôn biết những gì được ghim. Hãy sử dụng thủ thuật này mọi lúc khi bạn cần một cửa sổ tham chiếu tiện dụng mà không cần phải liên tục di chuyển mọi thứ xung quanh hoặc chuyển đổi qua lại. Scroll Lock là lựa chọn tốt vì hầu hết mọi người không sử dụng nó cho mục đích nào khác, nhưng bạn có thể thay đổi nó thành một phím khác nếu muốn.

1. Ngăn máy tính không rơi vào chế độ Sleep

Đôi khi bạn tải xuống và chuyển các file lớn hơn trên máy tính của mình. Toàn bộ quá trình có thể mất vài phút đến vài giờ. Vấn đề là quá trình tải xuống thường bị gián đoạn do máy tính rơi vào chế độ Sleep sau vài phút. Điều này luôn khiến mọi người bực bội vì việc thử lại hoặc tiếp tục tải xuống thường không thành công. Để giải quyết vấn đề, hãy tạo một script liên kết với các phím Ctrl + Alt + Shift + S để ngăn máy tính không rơi vào chế độ Sleep.

#Requires AutoHotkey v2.0
#SingleInstance Force

global on := false, endTime := 0

^!+s::{
global on, endTime
if !on {
hrs := InputBox("Enter hours (0 = infinite):", "Anti-Sleep").Value
if !IsNumber(hrs) || hrs return MsgBox("Invalid input.")
endTime := hrs ? A_TickCount + hrs*3600000 : 0
SetTimer(AntiSleep, 300000), SetTimer(CheckEnd, 1000), on := true
ToolTip("Anti-Sleep: ON" (hrs ? "`n" hrs "h" : ""), 500, 500), SetTimer(() => ToolTip(), -1500)
} else { ; Required braces for multi-line else block
SetTimer(AntiSleep, 0), SetTimer(CheckEnd, 0), on := false
ToolTip("Anti-Sleep: OFF", 500, 500), SetTimer(() => ToolTip(), -1000)
}
}

AntiSleep() => (MouseMove(1,0,0,"R"), MouseMove(-1,0,0,"R"))
CheckEnd() => endTime && A_TickCount >= endTime && Send("^!+s")
^!+x::Send("^!+s")

Script hoạt động bằng cách di chuyển chuột một chút sau mỗi 5 phút. Theo cách này, PC sẽ không ở chế độ chờ và ngủ. Bạn có thể mở rộng script để bao gồm cả bộ đếm thời gian hủy kích hoạt script sau một khoảng thời gian nhất định. Script cũng hiển thị một chú giải công cụ nhỏ khi bạn kích hoạt hoặc hủy kích hoạt script, do đó, bạn luôn biết được script có đang chạy hay không.